Drag[en]gine Wiki

This page is read only. You can view the source, but not change it. Ask your administrator if you think this is wrong.
{{tag>dragonscript behavior}}
<WRAP youarehere>
[[:start|Start Page]] >> [[main|DragonScript Scripting Language]] >> [[abstractions#behavior_elementsquick_and_easy_development|Behavior Elements: Quick and Easy Development]] >> **ECBehaviorVRControlDesktop**
</WRAP>

  * [[behaviors_use_cases|Behaviors Explained: By Use-Case]]
  * [[behaviors_a_to_z|Behaviors Explained: From A to Z]]

====== ECBehaviorVRControlDesktop ======

Behavior adding support to VR hand action to control desktops.

To be used with [[behavior_vrhandaction|BaseVRHandAction]] subclasses. Tracks [[behavior_vrhandpointat|ECBehaviorVRHandPointAt]]. If an element is pointed at that supports [[behavior_controldesktop|ECBehaviorControlDesktop]] moves the mouse pointer and uses trigger pulling to simulate mouse click. Each hand can individually interact with different [[behavior_controldesktop|ECBehaviorControlDesktop]]. Hand action has to call pointAt(), pointAtPull() and pointAtRelease() to interact.

====== Instance Counts ======

This behavior can be used only once on an element.

====== Element Class Properties ======

Element class properties have the prefix ''vrControlDesktop.'' .

====== Events ======

This behavior has no events.

====== Required Behaviors ======

  * [[behavior_vrhandpointat|ECBehaviorVRHandPointAt]]

====== Optional Behaviors ======

This behavior does not support optional behaviors.

====== Persistency ======

This behavior does not required element class to be persistable (setPersistable).

====== API Documentation ======

#@LinkApiDocDEDS2_HTML~classDragengine_1_1Scenery_1_1ECBehaviorVRControlDesktop.html,ECBehaviorVRControlDesktop~@#.

Since DragonScript Module Version ''1.12''

====== Use Cases ======

  * Simplifies creating BaseVRHandAction using [[behavior_vrhandpointat|ECBehaviorVRHandPointAt]] pointing at an element supporting [[behavior_controldesktop|ECBehaviorControlDesktop]].

====== Element Class Example ======

<code>
class MyElement extends BehaviorElementClass
  public var ECBehaviorVRPlayspace vrPlayspace
  public var ECBehaviorVRHand vrHandRight
  public var ECBehaviorVRHand vrHandLeft
  public var ECBehaviorVRHandPointAt vrRightHandPointAt
  public var ECBehaviorVRHandPointAt vrLeftHandPointAt
  public var ECBehaviorVRControlDesktop vrControlDesktopRight
  public var ECBehaviorVRControlDesktop vrControlDesktopLeft
  func new()
      vrPlayspace = ECBehaviorVRPlayspace.new(this)
      vrHandRight = ECBehaviorVRHand.new(this, vrPlayspace, InputDeviceType.vrRightHand, BaseVRActorClass.idVRRightHand)
      vrHandLeft = ECBehaviorVRHand.new(this, vrPlayspace, InputDeviceType.vrLeftHand, BaseVRActorClass.idVRLeftHand)
      vrRightHandPointAt = ECBehaviorVRHandPointAt.new(this, vrRightHand, BaseVRActorClass.idVRRightHand)
      vrLeftHandPointAt = ECBehaviorVRHandPointAt.new(this, vrLeftHand, BaseVRActorClass.idVRLeftHand)
      vrControlDesktopRight = ECBehaviorVRControlDesktop.new(this, vrHandRight, BaseVRActorClass.idVRRightHand)
      vrControlDesktopLeft = ECBehaviorVRControlDesktop.new(this, vrHandLeft, BaseVRActorClass.idVRLeftHand)
  end
end
</code>

Example of VR-Hand action using this behavior.

<code>
class MyHandAction extends BaseVRHandAction implements BAAVRTriggerInput
  protected var ECBehaviorVRControlDesktop.Instance controlDesktop
  
  // Create action.
  func new()
  end
  
  // Init behaviors. This stores aside the behavior matching the VR hand this action belongs to.
  protected func void initBehaviors()
    super.initBehaviors()
    
    if vrHand.getECBehavior().getID().equals(BaseVRActorClass.idVRRightHand)
      controlDesktop = ECBehaviorVRControlDesktop.getInstanceIn(actor, BaseVRActorClass.idVRRightHand)
    else
      controlDesktop = ECBehaviorVRControlDesktop.getInstanceIn(actor, BaseVRActorClass.idVRLeftHand)
    end
  end
  
  // Activate hand behavior. Enable hand point at to enable controlling desktops.
  func void activate(BehaviorElement actor, ECBehaviorVRHand.Instance vrHand)
    super.activate(actor, vrHand)
    
    handPointAt.setEnabled(true)
  end
  
  // Deactivate hand behavior. Disable hand point at and stop interacting with desktop.
  // Do not stop interacting here if you want to switch to another action that should
  // keep on using the desktop.
  func void deactivate()
    controlDesktop.pointAtRelease()
    handPointAt.setEnabled(false)
    
    super.deactivate()
  end
  
  // Frame update. Interact with control desktop if pointed at. The if check allows
  // to test various possible interactions stopping at the first one that works.
  // Make sure super.think(elapsed) is alway called even if exiting early
  func void think(float elapsed)
    if controlDesktop.pointAt()
      super.think(elapsed)
      return
    end
    
    // Here you could test for other possible interactions
    
    super.think(elapsed)
  end
  
  // Events by BAAVRTriggerInput we do not use for this example but have to be declared.
  func void triggerTouch()
  end
  
  func void triggerUntouch()
  end
  
  func void triggerAnalog(float value)
  end
  
  // Trigger is pulled. Sends left mouse press to desktop if one is controlled.
  // The if check allows to test various possible interactions stopping at the
  // first one that works.
  func void triggerPull()
    if controlDesktop.pointAtPull()
      return
    end
    
    // Here you could test for other possible interactions
  end
  
  // Trigger has been released. Sends left mouse release to desktop if one is
  // controlled. // The if check allows to test various possible interactions
  // stopping at the first one that works.
  func void triggerRelease()
    if controlDesktop.pointAtRelease()
      return
    end
  end
end
</code>

====== Behavior Factory ======

Using element class supporting adding behaviors the behavior can be added like this:
<code xml>
<?xml version='1.0' encoding='UTF-8'?>
<elementClass name='MyClass' class='GenericBehaviorElement'>
  <behavior type='ECBehaviorVRPlayspace'/>
  <behavior type='ECBehaviorVRHand' id='right'/>
  <behavior type='ECBehaviorVRHand' id='left'/>
  <behavior type='ECBehaviorVRHandPointAt' id='right'>
    <string name='vrHand'>right</string>
  </behavior>
  <behavior type='ECBehaviorVRHandPointAt' id='left'>
    <string name='vrHand'>left</string>
  </behavior>
  
  <behavior type='ECBehaviorVRControlDesktop' id='right'>
    <!-- required: use vr hand point at with id -->
    <string name='vrHandPointAt'>right</string>
    
    <!-- set element properties. omit property prefix if used inside behavior tag -->
    <string name='.name'>value</string>
  </behavior>
  
  <behavior type='ECBehaviorVRControlDesktop' id='left'>
    <string name='vrHandPointAt'>left</string>
  </behavior>
</elementClass>
</code>

====== Live Examples ======

  * [[https://github.com/LordOfDragons/deexamples|DEExamples Repository]]
Drag[en]gine Wiki

User Tools

Site Tools

Page Tools
